這一節，我們來看一下MCU（STM32F767IGTX）上電啟動后執行的代碼，也就是常說的啟動代碼。上一節里我們已經講過了CubeIDE工程的啟動代碼在Core/Startup文件夾下，是一個匯編源文件。

不是所有的啟動代碼都是匯編寫的，NXP就是用C寫的啟動代碼。可見C語言真是上得了廳堂（能編寫大型軟件，比如操作系統、編譯器），下得了廚房（直接跟硬件打交道也不在話下），在嵌入式領域那可是統治地位。

1. 編譯參數與全局變量

先把代碼放到下邊再分析。

.syntax unified
  .cpu cortex-m7
  .fpu softvfp
  .thumb


.global  g_pfnVectors
.global  Default_Handler


/* start address for the initialization values of the .data section. 
defined in linker script */
.word  _sidata
/* start address for the .data section. defined in linker script */  
.word  _sdata
/* end address for the .data section. defined in linker script */
.word  _edata
/* start address for the .bss section. defined in linker script */
.word  _sbss
/* end address for the .bss section. defined in linker script */
.word  _ebss
/* stack used for SystemInit_ExtMemCtl; always internal RAM used */

前4行是編譯參數，告訴編譯器編譯對象、參數，編譯器才好工作。

第6和第7行定義了兩個全局變量，下面的代碼里會用到。

接下來申明了5個外部變量，在鏈接文件中定義的，每個變量占有1個字，存儲的是一個地址，具體的含義代碼里已經有說明了，作用是在啟動時把data段從FLASH拷貝到RAM中，bss段清零。

2. 系統入口Reset_Handler

/**
 * @brief  This is the code that gets called when the processor first
 *          starts execution following a reset event. Only the absolutely
 *          necessary set is performed, after which the application
 *          supplied main() routine is called. 
 * @param  None
 * @retval : None
*/


    .section  .text.Reset_Handler
  .weak  Reset_Handler
  .type  Reset_Handler, %function
Reset_Handler:  
  ldr   sp, =_estack      /* set stack pointer */


/* Copy the data segment initializers from flash to SRAM */  
  ldr r0, =_sdata
  ldr r1, =_edata
  ldr r2, =_sidata
  movs r3, #0
  b LoopCopyDataInit


CopyDataInit:
  ldr r4, [r2, r3]
  str r4, [r0, r3]
  adds r3, r3, #4


LoopCopyDataInit:
  adds r4, r0, r3
  cmp r4, r1
  bcc CopyDataInit


/* Zero fill the bss segment. */
  ldr r2, =_sbss
  ldr r4, =_ebss
  movs r3, #0
  b LoopFillZerobss


FillZerobss:
  str  r3, [r2]
  adds r2, r2, #4


LoopFillZerobss:
  cmp r2, r4
  bcc FillZerobss


/* Call the clock system initialization function.*/
  bl  SystemInit   
/* Call static constructors */
    bl __libc_init_array
/* Call the application's entry point.*/
  bl  main
  bx  lr    
.size  Reset_Handler, .-Reset_Handler

系統上電后，默認會從FLASH的起始地址取指令執行，這個地方存放的是棧頂地址和中斷向量表，第一個中斷向量就是Reset_Handler，也即上電后會首先執行Reset_Handler這個函數，Reset_Handler是系統的入口（Entry Point）。

這段代碼的第10，11，12行指明了Reset_Handler這個函數在代碼段，且是弱函數，用戶可以改寫。

第13行是Reset_Handler函數的起始，14行Reset_Handler函數的第一條指令就是取棧頂地址送到SP中。

第17到31行是把data段從FLASH拷貝到RAM中，其中_sidata是data段在FLASH中的起始地址，_sdata是data段在RAM中的起始地址，_edata是data段在RAM中的結束地址。具體是如何復制的大家自己去看這段匯編代碼，匯編指令不清楚的可以去找F7的編程手冊（Programming Manual）。

第39行到45行是把bss段清零。代碼也靠大家自己去解讀。

第48行調用SystemInit函數，這個函數在system_stm32f7xx.c中，主要作用是設置FPU，根據需要設置中斷向量表的起始地址。

第50行調用__libc_init_array函數，這個函數是GCC提供的，其作用是初始化C庫。

第52行調用main函數，終于到了我們熟悉的地方了，用戶代碼的入口。

后邊的指令是執行不到的，因為main函數中有個無限循環。

分析到這里，大家就明白了，系統啟動后不是直接執行main函數的，執行main函數之前還有一些工作要做。所以，認為main函數是系統入口的觀點是不對的。

3. 意料外中斷的處理函數Default_Handler

/**
 * @brief  This is the code that gets called when the processor receives an 
 *         unexpected interrupt.  This simply enters an infinite loop, preserving
 *         the system state for examination by a debugger.
 * @param  None     
 * @retval None       
*/
    .section  .text.Default_Handler,"ax",%progbits
Default_Handler:
Infinite_Loop:
  b  Infinite_Loop
  .size  Default_Handler, .-Default_Handler

接下來又定義了一個函數——Default_Handler，這個函數里只有一個無限循環。主要作用是當遇到意料外的中斷時，都會調用Default_Handler來處理。什么是意料外的中斷呢？當用戶程序里沒有定義某一個中斷的中斷服務程序，但是某種情況下這個中斷又產生了，這個時候就要靠Default_Handler來處理了。這在調試的時候有用，進入Default_Handler后，產生中斷的原因，進入Default_Handler前運行的代碼等情況都被保存下來，可以提取查看，解決BUG。

4. 其余代碼

接下來的代碼就不放上來了。其實也不是代碼，是中斷向量和中斷服務函數的定義。這里的中斷向量的名稱和順序與F767的系統異常/中斷一一對應。